Public Sub Main()
    Dim U32LE       As UTF32Encoding
    Dim U32withED   As UTF32Encoding
    Dim U32noED     As UTF32Encoding
    Dim MyStr       As String
    Dim MyBytes()   As Byte
    
    Set Console.OutputEncoding = Encoding.UTF8
    
    ' Create an instance of UTF32Encoding using little-endian byte order.
    ' This will be used for encoding.
    Set U32LE = NewUTF32Encoding(False, True)
    
    ' Create two instances of UTF32Encoding using big-endian byte order: one with error detection and one without.
    ' These will be used for decoding.
    Set U32withED = NewUTF32Encoding(True, True, True)
    Set U32noED = NewUTF32Encoding(True, True, False)
    
    ' Create byte arrays from the same string containing the following characters:
    '    Latin Small Letter Z (U+007A)
    '    Latin Small Letter A (U+0061)
    '    Combining Breve (U+0306)
    '    Latin Small Letter AE With Acute (U+01FD)
    '    Greek Small Letter Beta (U+03B2)
    '    a high-surrogate value (U+D8FF)
    '    a low-surrogate value (U+DCFF)
    MyStr = t("za\u0306\u01FD\u03B2\uD8FF\uDCFF")
    
    ' Encode the string using little-endian byte order.
    ReDim MyBytes(0 To U32LE.GetByteCount(MyStr) - 1)
    U32LE.GetBytesEx MyStr, 0, Len(MyStr), MyBytes, 0
    
    ' Decode the byte array with error detection.
    Console.WriteLine "Decoding with error detection:"
    PrintDecodedString MyBytes, U32withED
    
    ' Decode the byte array without error detection.
    Console.WriteLine "Decoding without error detection:"
    PrintDecodedString MyBytes, U32noED
    
    Console.ReadKey
End Sub

Private Sub PrintDecodedString(ByRef Bytes() As Byte, ByVal Enc As Encoding)
    On Error GoTo Catch
    
    Console.WriteLine "  Decoded string: {0}", Enc.GetString(Bytes)
    
    GoTo Finally
    
Catch:
    Dim Ex As Exception
    Catch Ex, Err
    Console.WriteLine Ex.ToString
Finally:
    Console.WriteLine
End Sub